Radio/app/build.gradle

plugins {
    alias libs.plugins.android.application
    id 'kotlin-parcelize'
}

androidComponents {
    onVariants(selector().all()) { variant ->
        variant.outputs.forEach { output ->
            output.outputFileName.set("Radio.apk")
        }
    }
}

android {
    namespace 'com.michatec.radio'
    compileSdk 36

    defaultConfig {
        applicationId 'com.michatec.radio'
        minSdk 28
        targetSdk 36
        versionCode 145
        versionName '14.5'
        resourceConfigurations += ['en', 'de', 'el', 'nl', 'pl', 'ru','uk', 'ja', 'da', 'fr']
        externalNativeBuild {
            cmake {
                cppFlags ''
            }
        }
    }

    compileOptions {
        sourceCompatibility JavaVersion.VERSION_17
        targetCompatibility JavaVersion.VERSION_17
    }

    buildFeatures {
        buildConfig true
    }

    buildTypes {
        debug {
            minifyEnabled false
            shrinkResources false
            crunchPngs false
            proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'), 'proguard-rules.pro'
            applicationIdSuffix = ".debug"
        }	
	
        release {
            minifyEnabled true
            shrinkResources true
            crunchPngs true
            proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'), 'proguard-rules.pro'
        }
    }
    ndkVersion "29.0.14206865"
    externalNativeBuild {
        cmake {
            path file('src/main/cpp/CMakeLists.txt')
            version '3.22.1'
        }
    }
}

dependencies {
    implementation fileTree(dir: 'libs', include: ['*.jar'])

    // Google Stuff //
    implementation libs.material
    implementation libs.gson
    implementation libs.play.services.cast.framework

    // AndroidX Stuff //
    implementation libs.core.ktx
    implementation libs.activity.ktx
    implementation libs.palette.ktx
    implementation libs.preference.ktx
    implementation libs.media
    implementation libs.media3.exoplayer
    implementation libs.media3.exoplayer.hls
    implementation libs.media3.session
    implementation libs.media3.cast
    implementation libs.media3.datasource.okhttp
    implementation libs.navigation.fragment.ktx
    implementation libs.navigation.ui.ktx
    implementation libs.work.runtime.ktx
    implementation libs.leanback

    implementation libs.freedroidwarn
	
    // Volley HTTP request //
    implementation libs.volley
    implementation libs.material3
}