michas-droid/build.gradle

buildscript {
  repositories {
    google()
    mavenCentral()
    maven { url 'https://jitpack.io' }
  }

  dependencies {
    classpath 'com.android.tools.build:gradle:9.1.0'
    classpath 'org.jetbrains.kotlin:kotlin-gradle-plugin:2.3.10'
  }
}

apply plugin: 'com.android.application'

android {
  namespace 'com.michatec.store'
  compileSdk 36

  defaultConfig {
    applicationId 'com.michatec.store'
    minSdk 30
    targetSdk 36
    versionCode 16
    versionName '1.6'

    def languages = [ 'en' ]
    buildConfigField 'String[]', 'LANGUAGES', '{ "' + languages.join('", "') + '" }'
    resConfigs languages
  }

  buildFeatures {
    buildConfig = true
  }

  sourceSets {
    main {
        java.srcDirs += 'src/main/kotlin'
    }
  }

  compileOptions {
    sourceCompatibility JavaVersion.VERSION_17
    targetCompatibility JavaVersion.VERSION_17
  }

  flavorDimensions "distributor"
  productFlavors {
    michas {
      dimension "distributor"
      buildConfigField "boolean", "FLAVOR_FDROID", "false"
    }
    fdroid {
      dimension "distributor"
      buildConfigField "boolean", "FLAVOR_FDROID", "true"
    }
  }

  buildTypes {
    debug {
      minifyEnabled false
      shrinkResources false
    }
    release {
      minifyEnabled true
      shrinkResources false
    }
  }

  def keystorePropertiesFile = rootProject.file('keystore.properties')
  if (keystorePropertiesFile.exists()) {
    def keystoreProperties = new Properties()
    keystoreProperties.load(keystorePropertiesFile.newDataInputStream())

    def signing = [
      storeFile: keystoreProperties['store.file'],
      storePassword: keystoreProperties['store.password'],
      keyAlias: keystoreProperties['key.alias'],
      keyPassword: keystoreProperties['key.password']
    ]

    if (!signing.any { _, v -> v == null }) {
      signingConfigs {
        primary {
          storeFile file(signing.storeFile)
          storePassword signing.storePassword
          keyAlias signing.keyAlias
          keyPassword signing.keyPassword
          enableV2Signing false
        }
      }
    }
  }
}

repositories {
  google()
  mavenCentral()
  maven { url 'https://jitpack.io' }
}

dependencies {
  implementation 'org.jetbrains.kotlin:kotlin-stdlib:2.3.10'
  implementation 'androidx.fragment:fragment-ktx:1.8.9'
  implementation 'androidx.viewpager2:viewpager2:1.1.0'
  implementation 'androidx.vectordrawable:vectordrawable:1.2.0'
  implementation 'com.squareup.okhttp3:okhttp:5.3.2'
  implementation 'io.reactivex.rxjava3:rxjava:3.1.12'
  implementation 'io.reactivex.rxjava3:rxandroid:3.0.2'
  implementation 'com.fasterxml.jackson.core:jackson-core:2.21.1'
  implementation 'com.squareup.picasso:picasso:2.71828'
  implementation 'com.github.woheller69:FreeDroidWarn:V1.10'
}