michas-droid/build.gradle

buildscript {
  repositories {
    google()
    mavenCentral()
  }

  dependencies {
    classpath 'com.android.tools.build:gradle:9.0.1'
    classpath 'org.jetbrains.kotlin:kotlin-gradle-plugin:2.2.10'
  }
}

apply plugin: 'com.android.application'

android {
  namespace 'nya.kitsunyan.foxydroid'
  compileSdk 36

  defaultConfig {
    applicationId 'nya.kitsunyan.foxydroid'
    minSdk 30
    targetSdk 36
    versionCode 15
    versionName '1.5'

    def languages = [ 'en' ]
    buildConfigField 'String[]', 'LANGUAGES', '{ "' + languages.join('", "') + '" }'
    resConfigs languages
  }

  buildFeatures {
    buildConfig = true
  }

  sourceSets {
    main {
        java.srcDirs += 'src/main/kotlin'
    }
  }

  compileOptions {
    sourceCompatibility JavaVersion.VERSION_17
    targetCompatibility JavaVersion.VERSION_17
  }

  buildTypes {
    debug {
      minifyEnabled false
      shrinkResources false
    }
    release {
      minifyEnabled true
      shrinkResources false
    }
  }

  def keystorePropertiesFile = rootProject.file('keystore.properties')
  if (keystorePropertiesFile.exists()) {
    def keystoreProperties = new Properties()
    keystoreProperties.load(keystorePropertiesFile.newDataInputStream())

    def signing = [
      storeFile: keystoreProperties['store.file'],
      storePassword: keystoreProperties['store.password'],
      keyAlias: keystoreProperties['key.alias'],
      keyPassword: keystoreProperties['key.password']
    ]

    if (!signing.any { _, v -> v == null }) {
      signingConfigs {
        primary {
          storeFile file(signing.storeFile)
          storePassword signing.storePassword
          keyAlias signing.keyAlias
          keyPassword signing.keyPassword
          enableV2Signing false
        }
      }
    }
  }
}

repositories {
  google()
  mavenCentral()
}

dependencies {
  implementation 'org.jetbrains.kotlin:kotlin-stdlib:2.3.10'
  implementation 'androidx.fragment:fragment-ktx:1.8.9'
  implementation 'androidx.viewpager2:viewpager2:1.1.0'
  implementation 'androidx.vectordrawable:vectordrawable:1.2.0'
  implementation 'com.squareup.okhttp3:okhttp:5.3.2'
  implementation 'io.reactivex.rxjava3:rxjava:3.1.12'
  implementation 'io.reactivex.rxjava3:rxandroid:3.0.2'
  implementation 'com.fasterxml.jackson.core:jackson-core:2.21.1'
  implementation 'com.squareup.picasso:picasso:2.71828'
}